Крива Коха

int i = 0; // Кількість ітерацій 

void setup()
{
  size(600, 250); // Розміри вікна
}

void draw()
{
  // замалювати все в чорний корлі
  background(0);
  
  // відобразити білим кольором номер ітерації в лівому верхньому куті
  stroke(255);
  text(i, 10, 20);

  // намалювати Криву Коха за допомогою рекурсивних викликів
  recursion(i, 0, 200, 600, 200 );
}

void recursion(int i, float x1, float y1, float x2, float y2)
{
  // кінець рекурсивним викликам функції
  if (i == 0) 
  {
    // намалювати білу лінію від точки (x1, y1) до (x2, y2)
    stroke(255);
    line(x1, y1, x2, y2);
    return;
  }

  float alpha = atan2(y2 - y1, x2 - x1);// кут повороту
  float r = sqrt((x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1));// відстань між точками

  // обраховує 3 точки на прямій
  //       C
  //      / \
  // ----A   B----
  // ліва точка (ліва вершина трикутника)
  float xa = x1 + r * cos(alpha) / 3;
  float ya = y1 + r * sin(alpha) / 3;

  // центральна точка (верхня вершина трикутника)
  float xc = xa + r * cos(alpha - PI / 3) / 3;
  float yc = ya + r * sin(alpha - PI / 3) / 3;

  // права точка (права вершина трикутника)
  float xb = x1 + 2 * r * cos(alpha) / 3;
  float yb = y1 + 2 * r * sin(alpha) / 3;

  // рекурсивні виклики функції для 4 отриманих ліній
  recursion(i - 1, x1, y1, xa, ya);
  recursion(i - 1, xa, ya, xc, yc);
  recursion(i - 1, xc, yc, xb, yb);
  recursion(i - 1, xb, yb, x2, y2);
}
// перехід на наступну ітерації із нажиманням клавіші мишки
void mousePressed()
{
  ++i;
}

// клас представляє собою одну лінію, яка вміє генерувати на собі Криву Коха
class Segment
{
  // поля
  PVector start; // початок лінії
  PVector end; // кінець лінії
  // конструктор
  Segment(PVector start, PVector end)
  {
    this.start = start.copy();
    this.end = end.copy();
  }
  // методи
  // генеруємо Криву Коха на прямій
  Segment[] generate()
  {        
    // з одної прямою утворюється 4
    Segment[] children = new Segment[4];
    
    // 1/3 прямої
    PVector v = PVector.sub(end, start);
    v.div(3);
    
    // ліва вершина трикутника
    PVector ls = PVector.add(start, v);
    children[0] = new Segment(start, ls);
    
    // права вершина трикутника
    PVector rs = PVector.sub(end, v);
    children[3] = new Segment(rs, end);
    
    // верхня вершина трикутника
    v.rotate(-PI/3);
    PVector m = PVector.add(ls, v);
    children[1] = new Segment(ls, m);
    children[2] = new Segment(m, rs);
    
    // повертаємо Криву Коха для цієї лінії
    return children;
  }
  // відображаємо лінію
  void show()
  {
    stroke(255);
    line(start.x, start.y, end.x, end.y);
  }
}
// динамічний масив кривих, які будуть відображатись
ArrayList<Segment> segments;
int i;// номер ітерації

void setup()
{
  size(600, 600);// розмір вікна
  // ініціалізація полів
  segments = new ArrayList<Segment> ();
  i = 0;
  
  // встановлюємо 3 точки, вершини трикутника
  PVector leftPoint = new PVector(100, 200);
  PVector rightPoint = new PVector(500, 200);
  PVector bottomPoint = new PVector(300, 500);
  
  // зєднюємо ці точки прямими
  Segment s1 = new Segment(bottomPoint, leftPoint);
  Segment s2 = new Segment(leftPoint, rightPoint);
  Segment s3 = new Segment(rightPoint, bottomPoint);
  
  // додаємо ці прямі до масиву
  segments.add(s1);
  segments.add(s2);
  segments.add(s3);
}

void draw()
{
  // замалювати все в чорний колір
  background(0);
  
  // відобразити білим кольором номер ітерації в лівому верхньому куті
  fill(255);
  text(i, 10, 20);
  
  // відобразити усі прямі
  for (Segment segment : segments)
  {
    segment.show();
  }
}
// з нажиманням клавіші миші, обраховуємо прямі в наступній ітерації
void mousePressed()
{
  // тимчасовий динамічний масив для нових прямих
  ArrayList<Segment> nextGeneration = new ArrayList<Segment>(segments.size() * 4);
  // для кожної прямої із минулої ітерації...
  for (Segment segment: segments)
  {
    // ... обраховуємо Криву Коха
    Segment[] child = segment.generate();
    // усі прямі Кривої Коха запам'ятовуємо в тимчасовий масив
    for (Segment c : child)  nextGeneration.add(c);
  }
  // тимчасовий масив стає постійним, про масив на минулій ітерації забуваємо
  segments = nextGeneration;
  // збільшуємо номер ітерації
  ++i;
}